; Module/File:     Editor_JustificationSet.pb
; Function:        EditorGadget: sets the alignment of the whole text - Linux
; Author:          Omi
; Date:            Juli 20, 2014
; Version:         0.1
; Target Compiler: PureBasic 5.22/5.31/5.4/5.6
; Target OS:       Linux: (X/K/L)ubuntu, Mint, 32/64, Ascii/Uni
;--------------------------------------------------------------

EnableExplicit

; Object constants
#MainWin= 0
#Bt1    = 0
#CB1    = 1
#Edt1   = 2

#WinX   =300
#WinY   =200
#WinW   =300
#WinH   =200

Global.i gEvent, gQuit
Global.s gS= "Lorem ipsum dolor sit amet, consetetur sadipscing elitr, sed diam nonumy eirmod tempor invidunt ut labore et dolore magna aliquyam " + 
             "erat, sed diam voluptua. At vero eos et accusam et justo duo dolores et ea rebum. Stet clita kasd gubergren, no sea takimata sanctus " + 
             "est Lorem ipsum dolor sit amet."

If OpenWindow(#MainWin, #WinX, #WinY, #WinW, #WinH, "EditorGadget - Text justification", #PB_Window_SystemMenu)
	ComboBoxGadget(#CB1, 5, 2, 185, 30)
	AddGadgetItem(#CB1, -1, "#GTK_JUSTIFY_LEFT (Default)")
	AddGadgetItem(#CB1, -1, "#GTK_JUSTIFY_RIGHT")
	AddGadgetItem(#CB1, -1, "#GTK_JUSTIFY_CENTER")
	AddGadgetItem(#CB1, -1, "#GTK_JUSTIFY_FILL")
	SetGadgetState(#CB1, 0)
	EditorGadget(#Edt1, 5, 35, #WinW-10, #WinH-40, #PB_Editor_WordWrap)
	AddGadgetItem(#Edt1, -1, gS)
	
	gtk_text_view_set_wrap_mode_(GadgetID(#Edt1), #GTK_WRAP_WORD);  word-wise line break
	
	Repeat
		gEvent= WaitWindowEvent()
		
		Select gEvent
			Case #PB_Event_CloseWindow
				gQuit= #True
				
			Case #PB_Event_Gadget
				Select EventGadget()
					Case #CB1
						Select GetGadgetState(#CB1)
							Case #GTK_JUSTIFY_LEFT
								gtk_text_view_set_justification_(GadgetID(#Edt1), #GTK_JUSTIFY_LEFT)
							Case #GTK_JUSTIFY_RIGHT
								gtk_text_view_set_justification_(GadgetID(#Edt1), #GTK_JUSTIFY_RIGHT)
							Case #GTK_JUSTIFY_CENTER
								gtk_text_view_set_justification_(GadgetID(#Edt1), #GTK_JUSTIFY_CENTER)
							Case #GTK_JUSTIFY_FILL
								gtk_text_view_set_justification_(GadgetID(#Edt1), #GTK_JUSTIFY_FILL)
								; Abfrage:
								; gtk_text_view_get_justification_(GadgetID(#Edt1))
						EndSelect
						SetActiveGadget(#Edt1);                        Focus on text again
				EndSelect

		EndSelect
		
	Until gQuit
EndIf
; IDE Options = PureBasic 5.62 beta 1 (Linux - x86)
; CursorPosition = 21
; EnableXP
; CurrentDirectory = /home/charly-xubuntu/Programming/PureBasic/purebasic/
; EnableUnicode